Controllo numerico HEIDENHAIN TNC640

Titolo corso CORSO BASE DI PROGRAMMAZIONE

Lezione 12
Nome file ASOLE

0 BEGIN PGM ASOLE MM

1 ;BLK FORM 0.1 Z X-130 Y-70 Z-15
2 ;BLK FORM 0.2 X+130 Y+70 Z+3
3 TOOL CALL 5 Z S4400 F1000
4 * - FRESA D12 SGR
5 L Z+200 R0 FMAX M3
6 CYCL DEF 253 FRES. SCANAL. ~
Q215=+1 ;TIPO LAVORAZIONE ~
Q218=+52 ;LUNGH. SCANALATURA ~
Q219=+14 ;LARG. SCANALATURA ~
Q368=+0.2 ;QUOTA LATERALE CONS. ~
Q374=+0 ;ANGOLO DI ROTAZIONE ~
Q367=+0 ;POSIZ. SCANALATURA ~
Q207= AUTO ;AVANZAM. FRESATURA ~
Q351=+1 ;MODO FRESATURA ~
Q201=-4 ;PROFONDITA ~
Q202=+2 ;PROF. INCREMENTO ~
Q369=+0 ;PROFONDITA' CONSEN. ~
Q206= AUTO ;AVANZ. INCREMENTO ~
Q338=+4 ;INCREMENTO FINITURA ~
Q200=+2 ;DISTANZA SICUREZZA ~
Q203=+0 ;COORD. SUPERFICIE ~
Q204=+50 ;2. DIST. SICUREZZA ~
Q366=+2 ;PENETRAZIONE ~
Q385= AUTO ;AVANZAMENTO FINITURA ~
Q439=+1 ;RIF. AVANZAMENTO
7 ;
8 LBL "ASOLE"
9 CALL LBL 11
10 CALL LBL "CICLO"
11 CALL LBL "RESET"
12 CALL LBL 12
13 CALL LBL "CICLO"
14 CALL LBL "RESET"
15 CALL LBL 13
16 CALL LBL "CICLO"
17 CALL LBL "RESET"
18 CALL LBL 14
19 CALL LBL "CICLO"
20 CALL LBL "RESET"
21 CALL LBL 15
22 CALL LBL "CICLO"
23 CALL LBL "RESET"
24 CALL LBL 16
25 CALL LBL "CICLO"
26 CALL LBL "RESET"
27 LBL 0
28 ;
29 L Z+200 R0 FMAX M5
30 TOOL CALL 26 Z S4400 F600
31 * - FRESA D12 FINITURA
32 L Z+200 R0 FMAX M3 M8
33 Q215 = 2 ; TIPO DI LAVORAZIONE FINITURA
34 Q202 = 4 ; INCREMENTO Z
35 CALL LBL "ASOLE"
36 ;
37 L Z+200 R0 FMAX M5 M9
38 ;
39 CALL LBL 199
40 STOP M30
41 ;
42 LBL 11
43 CYCL DEF 7.0 PUNTO ZERO
44 CYCL DEF 7.1 X-50
45 CYCL DEF 7.2 Y-50
46 LBL 0
47 LBL 12
48 CYCL DEF 7.0 PUNTO ZERO
49 CYCL DEF 7.1 X+50
50 CYCL DEF 7.2 Y-50
51 LBL 0
52 LBL 13
53 CYCL DEF 7.0 PUNTO ZERO
54 CYCL DEF 7.1 X+50
55 CYCL DEF 7.2 Y+50
56 LBL 0
57 LBL 14
58 CYCL DEF 7.0 PUNTO ZERO
59 CYCL DEF 7.1 X-50
60 CYCL DEF 7.2 Y+50
61 LBL 0
62 LBL 15
63 CYCL DEF 7.0 PUNTO ZERO
64 CYCL DEF 7.1 X+100
65 CYCL DEF 7.2 Y+0
66 CYCL DEF 10.0 ROTAZIONE
67 CYCL DEF 10.1 ROT+90
68 LBL 0
69 LBL 16
70 CYCL DEF 7.0 PUNTO ZERO
71 CYCL DEF 7.1 X-100
72 CYCL DEF 7.2 Y+0
73 CYCL DEF 10.0 ROTAZIONE
74 CYCL DEF 10.1 ROT+90
75 LBL 0
76 LBL "RESET"
77 CYCL DEF 10.0 ROTAZIONE
78 CYCL DEF 10.1 ROT+0
79 CYCL DEF 7.0 PUNTO ZERO
80 CYCL DEF 7.1 X+0
81 CYCL DEF 7.2 Y+0
82 CYCL DEF 7.3 Z+0
83 LBL 0
84 LBL "CICLO"
85 L X+0 Y+0 R0 FMAX M99
86 LBL 0
87 LBL 199
88 END PGM ASOLE MM