/FILNAME,weldingstress,0

/PREP7 ! Weldments defined parameters

L=1E-1 ! Weldment length
W=1E-1 ! Weldment width
H=6E-3 ! Weldment height
U=20 ! Welding voltage
I=160 ! Welding current

V=0.01 ! Welding speed

YITA=0.7 ! Welding thermal efficiency
R=0.007 ! Effective heat arc radius
Q=U*I*YITA ! Arc thermal efficiency
Qm=3/3.1415/R**2*Q ! Center best spot heating flux
!*
ET,1,PLANE55
ET,2,SOLID70

MPTEMP,,,,,,,,
MPTEMP,1,20
MPTEMP,2,200
MPTEMP,3,500
MPTEMP,4,750
MPTEMP,5,1000
MPTEMP,6,1500
MPTEMP,7,1700
MPTEMP,8,2500

MPDATA,KXX,1,,50
MPDATA,KXX,1,,47
MPDATA,KXX,1,,40
MPDATA,KXX,1,,27
MPDATA,KXX,1,,30
MPDATA,KXX,1,,35
MPDATA,KXX,1,,40
MPDATA,KXX,1,,55

MPDATA,DENS,1,,7820
MPDATA,DENS,1,,7700
MPDATA,DENS,1,,7610
MPDATA,DENS,1,,7550
MPDATA,DENS,1,,7490
MPDATA,DENS,1,,7350
MPDATA,DENS,1,,7300
MPDATA,DENS,1,,7090
MPDATA,C,1,,460
MPDATA,C,1,,480
MPDATA,C,1,,530
MPDATA,C,1,,675
MPDATA,C,1,,670
MPDATA,C,1,,660
MPDATA,C,1,,780
MPDATA,C,1,,820

MPDATA,EX,1,,2.05E11
MPDATA,EX,1,,1.87E11
MPDATA,EX,1,,1.5E11
MPDATA,EX,1,,0.7E11
MPDATA,EX,1,,0.2E11
MPDATA,EX,1,,0.19E2
MPDATA,EX,1,,0.18E2
MPDATA,EX,1,,0.12e2

MPDATA,PRXY,1,,0.28
MPDATA,PRXY,1,,0.29
MPDATA,PRXY,1,,0.31
MPDATA,PRXY,1,,0.35
MPDATA,PRXY,1,,0.4
MPDATA,PRXY,1,,0.45
MPDATA,PRXY,1,,0.48
MPDATA,PRXY,1,,0.5

UIMP,1,REFT,,,20
MPDATA,ALPX,1,,1.1e-5
MPDATA,ALPX,1,,1.22e-5
MPDATA,ALPX,1,,1.39e-5
MPDATA,ALPX,1,,1.48e-5
MPDATA,ALPX,1,,1.34e-5
MPDATA,ALPX,1,,1.33e-5
MPDATA,ALPX,1,,1.32e-5
MPDATA,ALPX,1,,1.31e-5

TB,BISO,1,6,2,
TBTEMP,20
TBDATA,,220e6,0,,,,
TBTEMP,250
TBDATA,,175e6,0,,,,
TBTEMP,500
TBDATA,,80e6,0,,,,
TBTEMP,750
TBDATA,,40E6,0,,,,
TBTEMP,1000
TBDATA,,10E6,0,,,,
TBTEMP,1500
TBDATA,,1E-5,0,,,,

! Define key points

K,1,0,0,0
K,2,0,L,0
K,3,-W/2*0.15,L,0
K,4,-W/2*0.3,L,0
K,5,-W/2*0.5,L,0
K,6,-W/2,L,0
K,7,-W/2,0,0
K,8,-W/2*0.5,0,0
K,9,-W/2*0.3,0,0
K,10,-W/2*0.15,0,0
K,11,0,0,H

! Face by establishing key points

A,1,2,3,10
A,10,3,4,9
A,9,4,5,8
A,8,5,6,7

! Mesh
ESIZE,0.0012
AMESH,1

ESIZE,0.0025
AMESH,2

ESIZE,0.005
AMESH,3

ESIZE,0.0065
AMESH,4

! Setting unit drawn into a volume mesh

TYPE, 2
EXTOPT,ESIZE,2,0,
EXTOPT,ACLEAR,1
!*
EXTOPT,ATTR,1,0,0
REAL,_Z4
ESYS,0
!*
VOFFST,1,H, ,
VOFFST,2,H, ,
VOFFST,3,H, ,
VOFFST,4,H, ,
EPLOT

NUMMRG,ALL, , , ,LOW

! Transient thermal analysis

/SOL
!*
ANTYPE,4
!*
TRNOPT,FULL ! Complete set method
LUMPM,0

! Define Gaussian heat source function

*DEL,_FNCNAME
*DEL,_FNCMTID
*DEL,_FNC_C1
*DEL,_FNC_C2
*DEL,_FNC_C3
*DEL,_FNCCSYS
*SET,_FNCNAME,'GAOSI'
*DIM,_FNC_C1,,1
*DIM,_FNC_C2,,1
*DIM,_FNC_C3,,1
*SET,_FNC_C1(1),QM
*SET,_FNC_C2(1),V
*SET,_FNC_C3(1),R
*SET,_FNCCSYS,0
! /INPUT,HANJIE.func,,,1
*DIM,%_FNCNAME%,TABLE,6,19,1,,,,%_FNCCSYS%
!
! Begin of equation: Qm*exp(-3*({X}^2+({Y}-V*{TIME})^2)/R^2)
*SET,%_FNCNAME%(0,0,1), 0.0, -999
*SET,%_FNCNAME%(2,0,1), 0.0
*SET,%_FNCNAME%(3,0,1), %_FNC_C1(1)%
*SET,%_FNCNAME%(4,0,1), %_FNC_C2(1)%
*SET,%_FNCNAME%(5,0,1), %_FNC_C3(1)%
*SET,%_FNCNAME%(6,0,1), 0.0
*SET,%_FNCNAME%(0,1,1), 1.0, -1, 0, 0, 0, 0, 0
*SET,%_FNCNAME%(0,2,1), 0.0, -2, 0, 1, 0, 0, -1
*SET,%_FNCNAME%(0,3,1), 0, -3, 0, 1, -1, 2, -2
*SET,%_FNCNAME%(0,4,1), 0.0, -1, 0, 3, 0, 0, -3
*SET,%_FNCNAME%(0,5,1), 0.0, -2, 0, 1, -3, 3, -1
*SET,%_FNCNAME%(0,6,1), 0.0, -1, 0, 2, 0, 0, 2
*SET,%_FNCNAME%(0,7,1), 0.0, -3, 0, 1, 2, 17, -1
*SET,%_FNCNAME%(0,8,1), 0.0, -1, 0, 1, 18, 3, 1
*SET,%_FNCNAME%(0,9,1), 0.0, -4, 0, 1, 3, 2, -1
*SET,%_FNCNAME%(0,10,1), 0.0, -1, 0, 2, 0, 0, -4
*SET,%_FNCNAME%(0,11,1), 0.0, -5, 0, 1, -4, 17, -1
*SET,%_FNCNAME%(0,12,1), 0.0, -1, 0, 1, -3, 1, -5
*SET,%_FNCNAME%(0,13,1), 0.0, -3, 0, 1, -2, 3, -1
*SET,%_FNCNAME%(0,14,1), 0.0, -1, 0, 2, 0, 0, 19
*SET,%_FNCNAME%(0,15,1), 0.0, -2, 0, 1, 19, 17, -1
*SET,%_FNCNAME%(0,16,1), 0.0, -1, 0, 1, -3, 4, -2
*SET,%_FNCNAME%(0,17,1), 0.0, -1, 7, 1, -1, 0, 0
*SET,%_FNCNAME%(0,18,1), 0.0, -2, 0, 1, 17, 3, -1
*SET,%_FNCNAME%(0,19,1), 0.0, 99, 0, 1, -2, 0, 0
! End of equation: Qm*exp(-3*({X}^2+({Y}-V*{TIME})^2)/R^2)

TUNIF,20, ! Define the initial temperature

! Define convective heat transfer boundary

SFA,15,1,CONV,30,20
SFA,20,1,CONV,30,20

SFA,9,1,CONV,30,20
SFA,14,1,CONV,30,20
SFA,19,1,CONV,30,20
SFA,24,1,CONV,30,20
SFA,23,1,CONV,30,20

SFA,7,1,CONV,30,20
SFA,12,1,CONV,30,20
SFA,17,1,CONV,30,20
SFA,22,1,CONV,30,20

SFA,1,1,CONV,30,20
SFA,2,1,CONV,30,20
SFA,3,1,CONV,30,20
SFA,4,1,CONV,30,20

! Apply gaussian heat source

SFA,5,1,HFLUX, %GAOSI%
SFA,10,1,HFLUX, %GAOSI%

OUTRES,ALL,ALL,

TIME,L/V ! Setting the computation time

AUTOTS,-1
NSUBST,50,50,50
KBC,0
TSRES,ERASE
LSWRITE,1, ! Write load file 1
!*
TIME,20
AUTOTS,1
NSUBST,20,20,20
KBC,0
!*
TSRES,ERASE
LSWRITE,2,

TIME,50
AUTOTS,1
NSUBST,30,30,30
KBC,0
!*
TSRES,ERASE
LSWRITE,3,

TIME,1100
AUTOTS,1
NSUBST,105,105,105
KBC,0
!*
TSRES,ERASE
LSWRITE,4,

LSSOLVE,1,4,1, ! Start solving

! Enter thermal stress solution

/PREP7
ETCHG,TTS ! Thermal conversion to structural analysis
/SOL
ANTYPE,4
TRNOPT,FULL
LUMPM,0
NLGEOM,1
NROPT,FULL, ,OFF

! Define thermal stress calculation reference temperature

TREF,20,

! Set symmetrical displacement constraints

DA,6,SYMM

! Setting displacement constraints

DL,13, ,UY,
DL,10, ,UY,
DL,7, ,UY,
DL,4, ,UY,
DL,1, ,UZ,

*DO,I,1,50
LDREAD,TEMP,,,0.2*I, ,'weldingstress','rth',' ' ! Read the results of thermal analysis
OUTRES,ALL,ALL,
TIME,0.2*I
DELTIM,0.2,0.075,0.2,1
SOLVE
*ENDDO

*DO,I,1,20
LDREAD,TEMP,,,10+I*0.5, ,'weldingstress','rth',' '
OUTRES,ALL,ALL,
TIME,10+I*0.5
DELTIM,0.5,0.5,1,1
SOLVE
*ENDDO

*DO,I,1,30
LDREAD,TEMP,,,20+I, ,'weldingstress','rth',' '
OUTRES,ALL,ALL,
TIME,20+I
DELTIM,1,1,1,1
SOLVE
*ENDDO
*DO,I,1,105
LDREAD,TEMP,,,50+10*I, ,'weldingstress','rth',' '
OUTRES,ALL,ALL,
TIME,50+10*I
DELTIM,10,10,10,1
SOLVE
*ENDDO