UNIVERSIDAD DE EL SALVADOR

FACULTAD DE INGENIERA Y ARQUITECTURA

ESCUELA DE INGENIERA ELCTRICA
ANLISIS ELCTRICO I
CICLO I - 2017

Catedrtico: Ing. Gerardo Marvin Jorge Hernndez.

Instructor: Br. Cristian Antonio Aguilar Quintanilla.

Gua de Asignacin I: Ley de Ohm, Kirchhoff y Amplificadores Operacionales.

Asignacin 1. Calcular la potencia suministrada por la fuente de voltaje dependiente de

corriente.

* Asignacin 1.
* Gua de asignacin I.
* AEL115 Ciclo I-2017.

* Fuentes de tensin independientes.

V1 1 0 DC 80
V2 6 3 DC 30
Vx 2 3 DC 0
Vy 4 5 DC 0
* Fuentes de tensin dependientes de corriente
h1 6 5 Vx 15
* Resistencias.
R1 1 2 10
R2 3 4 20
R3 4 0 30
R4 6 0 40
.control
op
echo
echo La potencia suministrada por la fuente 15I1 es:
echo
let p=v(6,5)*i(vy)
print P
echo
echo Las corrientes i1 e i son:
echo
print i(Vx)
print i(Vy)
echo
.endc
.end

Como la potencia suministrada se calcula con la formula = +, donde es la corriente

que entra en el terminal negativo de la fuente y es la tensin de la fuente desde su terminal
positivo hacia su terminal negativo; podemos concluir que esta fuente realmente est
consumiendo (o disipando) energa, es una carga para la red.
Asignacin 2. Determinar el valor de Rx, para el cual absorba la mxima potencia en el
circuito mostrado.

* Asignacin 2
* Gua de simulacin I.
* AEL115 Ciclo I-2017.

* Fuentes de tensin independientes.

V1 1 5 DC 25
Vx 4 2 DC 0
Vy 2 3 DC 0
* Fuentes de voltaje dependiente de corriente.
h1 0 5 Vx 10
* Resistencias.
R1 1 2 40
R2 4 0 20
Rx 3 0 1
.control
* Anlisis de barrido en DC.
dc rx 1 100 1
plot i(Vy)*v(3)
+xlabel 'Rx [Ohm]'
+ylabel 'PRx [W]'
.endc
.end
Haciendo uso del Zoom Box se puede leer que el valor de Rx para que disipe la mxima
potencia es 16 , disipando una potencia de 1.5625 W.
Asignacin 3. Para el siguiente circuito determinar el valor de e . Identificar qu tipo
de configuracin se forma.

* Asignacin 3
* Gua de simulacin I.
* AEL115 Ciclo I-2017.

* Fuentes de tensin independientes.

V1 1 0 DC 1.5
V2 2 0 DC 2
V3 3 0 DC 1.2
Vx 6 5 DC 0
* Amplificadores Operacionales.
E1 6 0 0 4 10Meg
* Resistencias.
R1 1 4 20k
R2 2 4 10k
R3 3 4 6k
R4 4 5 8k
R5 5 0 4k
.control
op
echo
echo La tensin de salida Vo es:
echo
print V(5)
echo
echo La corriente io es:
echo
print i(Vx)
echo
.endc
.end
Asignacin Extra 1 (Asignacin 4). Encontrar el equivalente Thevenin visto desde los
terminales a y b aplicando el procedimiento de simulacin con el comando tf o utilizando
un interruptor controlado por tensin. No utilizar ningn elemento conectado entre los
terminales a y b.

Forma 1. Usando interruptor controlado por tensin:

* Asignacin Extra 1 Forma 1 usando interruptor controlado por tensin.

* Gua de Asignacin 1.
* AEL115 Ciclo I-2017

Vs 1 0 DC 10V
Vcontrol 3 0 DC 0V
Vx 2 0 DC 0V
* Asumiendo un valor inicial para Voc.
Voc 4 0 DC 0V
R1 1 x 8Ohm
R2 x a 4Ohm
R3 x w 16Ohm
R4 z 0 1Ohm
R5 z w 1Ohm
Rg 3 0 10Meg
Rth 4 0 10Ohm
E1 w 0 z a 10Meg
* Interruptor controlado por voltaje.
S1 a 2 3 0 SMOD
.model SMOD SW ( VT=0.001 VH=0.001 RON=0.001 ROFF=10e5 )
.control
destroy all
* Inicialmente el interruptor est abierto. Determinamos Voc:
op
echo
echo Voc es:
echo
print v(a)
* Cambiando el valor de Vcontrol para superar VT y producir un cortocircuito.
alter vcontrol=10
op
echo
echo Isc es:
echo
print i(Vx)
echo
echo Rth=Voc/Isc es:
let zth=op1.v(a)/op2.i(Vx)
echo
print zth
echo
.endc
.end

Forma 2. Usando comando tf:

* Asignacin Extra 1 Forma 2 usando comando tf.

* Gua de Asignacin 1.
* AEL115 Ciclo I-2017

Vs 1 0 DC 10
R1 1 x 8
R2 x y 4
R3 x w 16
R4 z 0 1
R5 z w 1
E1 w 0 z y 10Meg
Voc a 0 DC 0
Rth a b 1
.control
destroy all
tf v(y) vs
let voc=(transfer_function*@vs)
let rth=output_impedance
echo
echo La solucin usando el comando tf es:
echo
echo Voc es:
echo
print voc
echo
echo Rth es:
echo
print rth
echo
echo
.endc
.end

Forma 3. No solicitada, usando barrido en DC.

* Asignacin Extra 1 Forma 1 No solicitada Usando barrido en DC.

* Gua de Asignacin 1.
* AEL115 Ciclo I-2017

V1 1 0 DC 10
Vr q 0 DC 0
R1 1 x 8
R2 x y 4
R3 x w 16
R4 z w 1
R5 z 0 1
Rx y q 1
E1 w 0 z y 10Meg
.control
* Anlisis de barrido en DC.
dc rx 1 100 1
plot i(Vr)*v(y,q)
+xlabel 'Rx [Ohm]'
+ylabel 'PRx [W]'
.endc
.end
Asignacin Extra 2 (Asignacin 5). Resolver el circuito de la asignacin anterior, pero
cambiando el amplificador operacional ideal por el LF356 o el LMC6482A. Investigar en
internet los sub-circuitos de dichos componentes.

Paginas donde pueden encontrarse los sub-circuitos para muchos dispositivos electrnicos.

(C) National Semiconductor, Inc.:

http://spot.pcc.edu/~mfarrell/resources/spice/library%20directory/lm741.sub

Motorola Operational Amplifier Macromodel Library:

http://espice.ugr.es/espice/src/modelos_subckt/spice_complete/m_opamp.lib

* Diese Spice-Bibliothek kopieren in das Verzeichnis "C:\Program

Files\LTC\LTspiceIV\lib\sub":
https://home.zhaw.ch/hhrt/LTspice/ZHAW.lib

Usando el comando tf se hace la solucin para este problema.

* Asignacin Extra 1 usando comando tf.

* Gua de Asignacin 1.
* AEL115 Ciclo I-2017

Vs 1 0 DC 10V
VDD 2 0 DC 15V
VSS 3 0 DC -15V
R1 1 x 8Ohm
R2 x y 4Ohm
R3 x w 16Ohm
R4 z 0 1Ohm
R5 z w 1Ohm
*XAMP <Entrada no inversora> <Entrada inversora> <Alimentacin Positiva>
* + <Alimentacin Negativa> <Nodo de Salida> <Nombre AO>
*X1_LF356 z y 2 3 w LF356_MC
*X1_LMC6482A z y 2 3 w LMC6482A
* Valores iniciales asumidos para Voc y Rth.
Voc a 0 DC 0V
Rth a b 1Ohm
* LF356 operational amplifier
*"MACROMODEL" SUBCIRCUIT
*
* CONNECTIONS:
* 1 - NON-INVERTING INPUT
* 2 - INVERTING INPUT
* 3 - POSITIVE POWER SUPPLY
* 4 - NEGATIVE POWER SUPPLY
* 5 - OUTPUT
*
.SUBCKT LF356_MC 1 2 3 4 5
*
c1 11 12 8.660E-12
c2 6 7 9.50E-12
dc 5 53 dx
de 54 5 dx
dlp 90 91 dx
dln 92 90 dx
dp 4 3 dx
egnd 99 0 poly(2) (3,0) (4,0) 0 .5 .5
fb 7 99 poly(5) vb vc ve vlp vln 0 13.26E6 -10E6 10E6 10E6 -10E6
ga 6 0 11 12 377.0E-6
gcm 0 6 10 99 3.770E-9
iss 3 10 dc 120.0E-6
hlim 90 0 vlim 1K
j1 11 2 10 jx
j2 12 1 10 jx
r2 6 9 100.0E3
rd1 4 11 2.653E3
rd2 4 12 2.653E3
ro1 8 5 30
ro2 7 99 30
rp 3 4 6.000E3
rss 10 99 1.667E6
vb 9 0 dc 0
vc 3 53 dc 3.6
ve 54 4 dc 3.6
vlim 7 8 dc 0
vlp 91 0 dc 20
vln 0 92 dc 20
.model dx D(Is=800.0E-18)
.model jx PJF(Is=15.00E-12 Beta=1.184E-3 Vto=-1)
.ends
*//////////////////////////////////////////////////////////////////////
* (C) National Semiconductor, Inc.
* Models developed and under copyright by:
* National Semiconductor, Inc.
*/////////////////////////////////////////////////////////////////////
* Legal Notice: This material is intended for free software support.
* The file may be copied, and distributed; however, reselling the
* material is illegal
*//////////////////////////////////////////////////////////
*LMC6482A CMOS Dual OP-AMP MACRO-MODEL
*//////////////////////////////////////////////////////////
* connections: non-inverting input
* | inverting input
* | | positive power supply
* | | | negative power supply
* | | | | output
* | | | | |
* | | | | |
.SUBCKT LMC6482A 1 2 99 50 40
* CAUTION: SET .OPTIONS GMIN=1E-16 TO CORRECTLY MODEL INPUT BIAS
CURRENT.
*Features:
*Operates from single or dual supplies
*Rail-to-rail input and output swing
*Ultra low input current = 10fA
*Slew rate = 1.2V/uS
*NOTE: Model is for single device only and simulated
* supply current is 1/2 of total device current.
* Noise is not modeled.
* Asymmetrical gain is not modeled.
*****************INPUT STAGE**************
I1 99 4 17U
M1 5 2 4 99 MOSFET
R3 5 50 5.651K
M2 6 7 4 99 MOSFET
R4 6 50 5.651K
*Fp2=5.9 MHz
C4 5 6 2.3868P
G0 98 9 6 5 4.4165E-2
R0 98 9 1K
DP1 1 99 DA
DP2 50 1 DB
DP3 2 99 DB
DP4 50 2 DA
*For accurate Ib , set GMIN<=1E-16 on .OPTIONS line.
***********COMMON MODE EFFECT***********
I2 99 50 420.5U
*^Quiescent current
EOS 7 1 POLY(1) 16 49 .75E-3 1
*Offset voltage..........^
R8 99 49 40K
R9 49 50 40K
***************POLE STAGE***************
*Fp=13.3 MHz
G3 98 15 9 49 1E-3
R12 98 15 1K
C5 98 15 11.967P
************POLE/ZERO STAGE*************
*Fp=600 KHz, Fz= 1.4MHz
G5 98 18 15 49 1E-3
R14 98 18 1K
R15 98 19 750
C6 19 18 151.58P
*********COMMON-MODE ZERO STAGE*********
*Fpcm=20 KHz
G4 98 16 POLY(2) 1 49 2 49 0 2.812E-8 2.812E-8
L2 98 17 7.958M
R13 17 16 1K
**************SECOND STAGE**************
EH 99 98 99 49 1
G1 98 29 18 49 5.6667E-6
R5 98 29 100.37MEG
V2 99 8 1.56
D1 29 8 DX
D2 10 29 DX
V3 10 50 1.56
**************OUTPUT STAGE**************
F6 99 50 VA7 1
*^Dynamic supply current
F5 99 35 VA8 1
D3 36 35 DX
VA7 99 36 0
D4 35 99 DX
E1 99 37 99 49 1
VA8 37 38 0
G6 38 40 49 29 16.667E-3
R16 38 40 2.3886K
V4 30 40 .77
D5 30 99 DX
V5 40 31 .77
D6 50 31 DX
*Fp1=2.343 Hz
C3 29 39 17P
R6 39 40 1K
***************MODELS USED**************
.MODEL DA D(IS=2E-14)
.MODEL DB D(IS=1E-14)
.MODEL DX D(IS=1E-14)
.MODEL MOSFET PMOS(VTO=0 KP=1.842E-3)
.ENDS
*
.control
destroy all
tf v(y) vs
let voc=(transfer_function*@vs)
let rth=output_impedance
echo
echo La solucin usando el comando tf es:
echo
echo Voc es:
echo
print voc
echo
echo Rth es:
echo
print rth
echo
echo
.endc
.end

Solucin para el LF356.

 Solucin para el LMC6482A.

La razn por la cual no coinciden los resultados usando sub-circuitos de amplificadores

operacionales en lugar de dispositivos ideales, es debido a que estos si cuentan con una
resistencia de entrada finita y una resistencia de salida distinta de cero.