/prep7

!!! point forming revolute joint

k,1,100,100,2500
k,2,100,100,500
k,11,100,100,2500
k,12,100,100,500
k,21,100,50,2500 !!! Points to be grounded
k,22,100,50,500
!!!Links
k,3,100,100,1500
k,4,100,500,1500
k,5,100,500,500
!!! ************** Element Types
ET,1,MPC184 !!! For rigid beams
KEYOPT,1,1,1 !!! Rigid Beam
KEYOPT,1,2,1 !!! Lagrange Multiplier
ET,2,MPC184 !!! For revolute joints
KEYOPT,2,1,6 !!! Revolute joint
KEYOPT,2,4,0 !!! x - Axis revolute
ET,4,Conta176 !!! For modeling rigid contact surface of rigid body
KEYOPT,4,2,2 !!! Constraint (MPC) option
KEYOPT,4,4,0 !!! Generate rigid MPC constraint
KEYOPT,4,12,5 !!! Bonded behaviour between pilot node
!! and contact surface
ET,5,Targe170
KEYOPT,5,2,1 !!! User defined constraints enabled.
KEYOPT,5,4,0 !!! Create CE's for all DOF
nkpt,1,1
nkpt,2,2
nkpt,11,11
nkpt,12,12
nkpt,21,21
nkpt,22,22
nkpt,3,3
nkpt,4,4
nkpt,5,5
!!! ********* Defining Rigid links with mpc beam element ********* !!!
TYPE,1
EN,1,1,3
EN,2,3,2
EN,3,3,4

EN,4,4,5
!!! ***** Rigid Links defined ***** !!!

!!! *************** Define Local CS ************* !!!

LOCAL,11,0,100,100,2500
CSYS,0
LOCAL,12,0,100,100,500
CSYS,0
!!!*******************************************************
!!! **********Define Revolute Joints ************
!!!!! *******************************************************
TYPE,2 !!! START Rev1
REAL,11
csys,11
nrotat,1
nrotat,11
SECNUM,11
SECTYPE,11,JOINT,REVO,Rev1
SECJOINT,,11,11
EN,11,1,11 !!! END Rev1
!!!!! *******************************************************
TYPE,2 !!! START Rev2
REAL,12
csys,12
nrotat,2
nrotat,12
SECNUM,12
SECTYPE,12,JOINT,REVO,Rev2
SECJOINT,,12,12
EN,12,2,12 !!! END Rev2
!!!!! *******************************************************
CSYS,0
!!! Target and contact elements for grounding
!!!***

REAL,21
TYPE,5
TSHAP,PILO
EN,21,21
TSHAP
TYPE,4
EN,22,11,21
!!!***
REAL,22
TYPE,5
TSHAP,PILO
EN,23,22
TSHAP
TYPE,4
EN,24,12,22
!!!
FINISH
/SOLU
ANTYPE,0
NLGEOM,ON
NSUBST,10,30,10
CSYS,0
D,21,all,0
D,22,all,0
F,5,FZ,-5000
SOLVE
FINISH
/POST1
ESEL,S,ELEM,,11
ESEL,A,ELEM,,12
ETABLE,RforceX,SMISC,1 !!! Joint force X
ETABLE,RforceY,SMISC,2 !!! Joint force Y
ETABLE,RforceZ,SMISC,3 !!! Joint force Z
ALLSEL
FINISH